基于JSON的简单本地化

///@desc Initialize
/* 确保已勾选 "Persistent（持久）" 属性！
启动游戏时创建此对象。它必须在整个游戏过程中保持激活状态。*/

//将默认语言设置为 ID 0。 以后添加保存/加载选项功能时可以更改。
global.currentLanguage = 0;

// 加载并解析可用本地化列表
var _availableLangsJsonStr = load_json_file_to_string("localization/availableLanguages.json");
availableLangsStruct = json_parse(_availableLangsJsonStr);

localizedStrings = {}; //初始化本地化字符串结构
set_language(global.currentLanguage);

///@desc 返回从 JSON 文件加载的 JSON 字符串，并过滤掉（技术上非法的）注释
///@arg  {string} jsonFilePath JSON 文件的路径，例如 "localization/stringsEN.json"
///@returns {string} JSON 字符串
function load_json_file_to_string(jsonFilePath) {
    var _jsonFile = file_text_open_read(jsonFilePath); //打开文本文件
    var _jsonStr = "";
    var _stringLine = "";
    var _commentPosition = 0;
    if (_jsonFile != -1) { //如果文件成功打开
        while (!file_text_eof(_jsonFile)) { //运行至文件末尾
            _stringLine = file_text_readln(_jsonFile); //读取下一行
            _stringLine = string_trim(_stringLine); //删除行首和行尾的空白处
            _commentPosition = string_pos("//", _stringLine); //检查注释
            if (_commentPosition > 0) { //发现注释
                _stringLine = string_copy(_stringLine, 1, _commentPosition-1); //移除注释
            }

            _jsonStr += _stringLine; //为字符串添加一行
        }
        file_text_close(_jsonFile); //关闭文本文件
        return _jsonStr; //返回文件内容的字符串
    }
    else {
        throw ("File "+jsonFilePath+" not found!"); //错误：未找到文件
    }
}

///@desc 设置游戏语言
///@arg {real} [langId] 根据 availableLanguages.json 中的列表顺序，选择要使用的语言的 ID 号
function set_language(langId) {
    global.currentLanguage = langId;
    //首先加载游戏的母语（此处为英语）本地化版本
    var _defaultJsonStr = load_json_file_to_string("localization/"+obLocalization.availableLangsStruct.langs[0].stringsFile);
    obLocalization.localizedStrings = json_parse(_defaultJsonStr);
    set_font_for_language(); //如果不想自动更改字体，请移除或注释此项

    //加载其他语言以覆盖母语。这样可以确保任何丢失的字符串都能
    //默认使用游戏的母语，而不会导致游戏崩溃。
    if (global.currentLanguage > 0) {
        var _localizationJsonStr = load_json_file_to_string("localization/"+obLocalization.availableLangsStruct.langs[global.currentLanguage].stringsFile);
        var _replacementStrings = json_parse(_localizationJsonStr);

        //逐步完成并替换字符串
        var _sectionNames = variable_struct_get_names(_replacementStrings);
        for (var _j = array_length(_sectionNames)-1; _j >= 0; --_j) {
            var _sectionName = _sectionNames[_j];
            var _sectionData = _replacementStrings[$ _sectionName];
            var _sectionDataArr = variable_struct_get_names(_sectionData);
            for (var _k = array_length(_sectionDataArr)-1; _k >= 0; --_k) {
                var _locReference = _sectionDataArr[_k];
                var _locText = _replacementStrings[$ _sectionName][$ _locReference];
                obLocalization.localizedStrings[$ _sectionName][$ _locReference] = _locText;
            }
        }
    }
}

///@desc 将字体设置为 availableLanguages.json 中为给定语言指定的字体
///@arg {real} [forceLangId] 为给定的语言 ID 选择字体。默认为当前语言。
function set_font_for_language(forceLangId = global.currentLanguage){
    var _fontName = obLocalization.availableLangsStruct.langs[forceLangId].font;
    var _fontIndex = asset_get_index(_fontName);
    draw_set_font(_fontIndex);
}

#macro LOCALIZE obLocalization.localizedStrings
#macro localize obLocalization.localizedStrings

draw_text(683,32,LOCALIZE.menu.letsMakeGames);

set_language(langId);